REPORT z_alv_cdhdr_cdpos.
*---------------------------------------------------------------------*
* This ALV report displays change document tables CDHDR and CDPOS *
*---------------------------------------------------------------------*
* Author : Michel PIOUD *
* Email : mpioud@yahoo.fr HomePage : http://www.geocities.com/mpioud *
*---------------------------------------------------------------------*
TYPE-POOLS slis. " Global ALV types
DATA : cdhdr TYPE cdhdr. " Change document header
SELECT-OPTIONS :
s_objcls FOR cdhdr-objectclas OBLIGATORY,
s_objtid FOR cdhdr-objectid,
s_chngnr FOR cdhdr-changenr,
s_usrnam FOR cdhdr-username DEFAULT sy-uname,
s_udate FOR cdhdr-udate DEFAULT sy-datum,
s_time FOR cdhdr-utime,
s_tcode FOR cdhdr-tcode,
s_plncnr FOR cdhdr-planchngnr,
s_chngno FOR cdhdr-act_chngno,
s_wsplnd FOR cdhdr-was_plannd,
s_chngid FOR cdhdr-change_ind.
SELECTION-SCREEN SKIP.
PARAMETERS p_max TYPE numc3 OBLIGATORY DEFAULT '200'.
*---------------------------------------------------------------------*
TYPES :
BEGIN OF ty_s_cdhdr.
INCLUDE STRUCTURE cdhdr.
TYPES : checkbox,
END OF ty_s_cdhdr,
BEGIN OF ty_s_cdpos.
INCLUDE STRUCTURE cdpos.
TYPES : checkbox,
END OF ty_s_cdpos.
*---------------------------------------------------------------------*
DATA :
* Layout for ALV
gs_layout TYPE slis_layout_alv,
* Change document header
t_cdhdr TYPE TABLE OF ty_s_cdhdr.
*---------------------------------------------------------------------*
START-OF-SELECTION.
* Read Change document header
SELECT * INTO TABLE t_cdhdr
UP TO p_max ROWS
FROM cdhdr
WHERE objectclas IN s_objcls
and objectid in s_objtid
and changenr in s_chngnr
AND username IN s_usrnam
AND udate IN s_udate
AND utime IN s_time
AND tcode IN s_tcode
AND planchngnr IN s_plncnr
AND act_chngno IN s_chngno
AND was_plannd IN s_wsplnd
AND change_ind IN s_chngid.
gs_layout-zebra = 'X'.
gs_layout-colwidth_optimize = 'X'.
gs_layout-box_fieldname = 'CHECKBOX'.
* Display ALV
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_callback_program = sy-cprog
i_callback_user_command = 'USER_COMMAND'
i_structure_name = 'CDHDR'
is_layout = gs_layout
TABLES
t_outtab = t_cdhdr.
*---------------------------------------------------------------------*
* FORM USER_COMMAND *
*---------------------------------------------------------------------*
FORM user_command USING u_ucomm TYPE syucomm
us_selfield TYPE slis_selfield. "#EC CALLED
* Macro definition
DEFINE m_sort.
add 1 to ls_sort-spos.
ls_sort-fieldname = &1.
ls_sort-up = 'X'.
append ls_sort to lt_sort.
END-OF-DEFINITION.
DATA :
ls_cdhdr TYPE ty_s_cdhdr,
ls_sort TYPE slis_sortinfo_alv,
lt_sort TYPE slis_t_sortinfo_alv,
* Change document items
lt_cdpos TYPE TABLE OF ty_s_cdpos.
CASE u_ucomm.
WHEN '&IC1'.
PERFORM check_marked USING us_selfield.
* Read Change document items
LOOP AT t_cdhdr INTO ls_cdhdr WHERE checkbox = 'X'.
SELECT * APPENDING TABLE lt_cdpos
FROM cdpos
WHERE objectclas = ls_cdhdr-objectclas
AND objectid = ls_cdhdr-objectid
AND changenr = ls_cdhdr-changenr.
ENDLOOP.
m_sort 'CHANGENR'.
* Display ALV
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_structure_name = 'CDPOS'
is_layout = gs_layout
it_sort = lt_sort
TABLES
t_outtab = lt_cdpos.
ENDCASE.
ENDFORM. " USER_COMMAND
*---------------------------------------------------------------------*
* Form CHECK_MARKED
*---------------------------------------------------------------------*
* What has been marked in t_cdhdr
*---------------------------------------------------------------------*
FORM check_marked USING us_selfield TYPE slis_selfield.
FIELD-SYMBOLS :
<cdhdr> TYPE ty_s_cdhdr.
READ TABLE t_cdhdr TRANSPORTING NO FIELDS WITH KEY checkbox = 'X'.
IF NOT sy-subrc IS INITIAL AND
NOT us_selfield-tabindex IS INITIAL.
READ TABLE t_cdhdr INDEX us_selfield-tabindex ASSIGNING <cdhdr>.
<cdhdr>-checkbox = 'X'.
ENDIF.
ENDFORM. " CHECK_MARKED
***************** END OF PROGRAM Z_ALV_CDHDR_CDPOS ********************
번호 | 제목 | 글쓴이 | 날짜 | 조회 수 |
---|---|---|---|---|
67 | REPORT z_alv_smartforms [2] | 노름마치 | 2007.11.05 | 4210 |
66 | REPORT z_alv_rsusr200 [1] | 노름마치 | 2007.11.05 | 4287 |
65 | ref 소스 [4] | 풍운사랑 | 2007.09.07 | 4308 |
64 | REPORT z_email_abap_report [1] | 노름마치 | 2007.11.05 | 4377 |
63 | REPORT z_list_user_profiles [1] | 노름마치 | 2007.11.05 | 4459 |
62 | REPORT z_alv_standard_text [1] | 노름마치 | 2007.11.05 | 4492 |
61 | REPORT z_password [1] | 노름마치 | 2007.11.05 | 4520 |
60 | REPORT z_dbbrowser [2] | 노름마치 | 2007.11.05 | 4574 |
59 | BDC 샘플소스(UPLODATE DATA) [7] | sapjoy | 2007.03.26 | 4615 |
58 | ALV Grid 코드 샘플 [10] | sapjoy | 2007.03.26 | 4676 |
57 | REPORT z_mychat [1] | 노름마치 | 2007.11.05 | 4745 |
» | REPORT z_alv_cdhdr_cdpos [1] | 노름마치 | 2007.11.05 | 4802 |
55 | REPORT z_exec_program [4] | 노름마치 | 2007.11.12 | 4904 |
54 | REPORT z_downup_table [1] | 노름마치 | 2007.11.05 | 4957 |
53 | SELECT-OPTIONS 문법 [5] | sapjoy | 2006.12.28 | 4968 |
52 | 모든 사용자의 화면에 메세지를 보내는 소스 [4] | 아밥공주 | 2007.04.02 | 5004 |
51 | internal table to an XML file [4] | BlackBean | 2007.06.04 | 5040 |
50 | REPORT z_se16 [2] | 노름마치 | 2007.11.05 | 5042 |
49 | REPORT z_memory_game [1] | 노름마치 | 2007.11.05 | 5200 |
48 | 웹 연동시키기 [2] | 아밥공주 | 2007.04.02 | 5282 |
유용하게 사용하겠습니다. 감사합니다^^